print("Initializing 'NA03 - ZCM/New Alterlite recipes and content for New Alterlite'...");

// OreDicts
val nAtlItem = <ore:gemAlterlitium>;
nAtlItem.add(<zcm_newalterlite:alterlitium>);

val nAtlOre = <ore:oreAlterlitium>;
nAtlOre.add(<zcm_newalterlite:alterlitiumore>);

val nAtlBlock = <ore:blockAlterlitium>;
nAtlBlock.add(<zcm_newalterlite:alterlitiumblock>);

// ------------------------------------------
// Alterlitum Block
recipes.addShaped("zcm_na_alterlitiumblock_recipe", <zcm_newalterlite:alterlitiumblock>, 
	[[<ore:gemAlterlitium>, <ore:gemAlterlitium>, <ore:gemAlterlitium>], 
	[<ore:gemAlterlitium>, <ore:gemAlterlitium>, <ore:gemAlterlitium>], 
	[<ore:gemAlterlitium>, <ore:gemAlterlitium>, <ore:gemAlterlitium>]]);

// Alterlitum Lamp
recipes.addShaped("zcm_na_alterlitiumlamp_recipe", <zcm_newalterlite:alterlitiumlamp> * 4, 
	[[<ore:blockAlterlitium>, <ore:blockAlterlitium>, <ore:blockAlterlitium>], 
	[<ore:blockAlterlitium>, <minecraft:glowstone>, <ore:blockAlterlitium>], 
	[<ore:blockAlterlitium>, <ore:blockAlterlitium>, <ore:blockAlterlitium>]]);

// Alterlitum Lamp (Pedestal)
mods.pedestalcrafting.Pedestal.addRecipe(<zcm_newalterlite:alterlitiumlamp> * 4, 160, <minecraft:glowstone>, [
    <ore:blockAlterlitium>,
    <ore:blockAlterlitium>,
    <ore:blockAlterlitium>,
    <ore:blockAlterlitium>,
    <ore:blockAlterlitium>,
    <ore:blockAlterlitium>,
    <ore:blockAlterlitium>,
    <ore:blockAlterlitium>
], [["endRod", "2"]], [["villagerhappy", "50"]], [["portal", "25"]]);

// Parchment
recipes.addShaped("zcm_na_parchment_recipe", <zcm_newalterlite:parchment>, 
	[[<ore:fiberHemp>, <ore:leather>, <ore:fiberHemp>], 
	[<ore:fiberHemp>, <ore:leather>, <ore:fiberHemp>], 
	[<ore:fiberHemp>, <ore:leather>, <ore:fiberHemp>]]);

// Unmarked Scroll
recipes.addShaped("zcm_na_unmarkedscroll_recipe", <zcm_newalterlite:emptyscroll>, 
	[[null, <zcm_newalterlite:parchment>, null], 
	[null, <ore:paper>, null], 
	[null, <ore:paper>, null]]);

// Attuned Pearl
recipes.addShapeless("zcm_na_attunedpearl_recipe", <zcm_newalterlite:attunedpearl>, [<ore:enderpearl>, <naturesaura:gold_powder>]);

// Sunlime
recipes.addShapeless("zcm_na_sunlime_recipe", <zcm_newalterlite:sunlime>, [<ore:foodLemon>, <naturesaura:aura_bottle>.withTag({stored_type: "naturesaura:overworld"})]);



print("Initialization of 'NA03 - ZCM/New Alterlite recipes and content for New Alterlite' has been completed.");